아두이노(arduino) 심박센서 (heart rate sensor) 심박수 측정 example code

하드 정리 중 예전에 만든 아두이노에서 심박센서를 사용하여 심박수 측정하는 소스 코드가 있어, 이를 블로그 글로 남긴다.

인터넷 쇼핑몰에서 쉽게 구할 수 있는 저렴함 센서가 사용 되었으며, 연결은 아래 그림과 같이 연결 되었다. 
  
심박센서의 하트 부위에 손가락을 올려 놓고, 아날로그 A0값을 읽으면 심박의 움직임에 따라 A0값이 변하는 동작이 간단한 센서이다. 아래 그림의 왼쪽은 일정 시간 간격 마다 A0값을 읽어 시리얼 플로터로 본 심박에 따른 데이터이고, 오른쪽은 평균 필터를 사용해 노이즈를 제거한 후 시리얼 플로터로 본 데이터이다.
 
심박수는 수집된 데이터에서 threshold를 넘는 peak들의 시간 간격을 측정하여 계산한다. 
peak위치를 찾는 방법은 여러 가지 방법이 있으나, 소스에 구현된 방법은 신호의 기울기가 +에서 0또는 -로 바뀌는 위치를 peak으로 선정하도록 하였다.
심장이 t시간동안 N회 뛰는 경우 심박수는 heart rate bpm = (N/t)*60 을 표현 할 수 있다.
 
threshold는 데이터를 보고 임의로 정했으며, 측정 데이터에 따라 자동으로 정하고 싶을 때는 cfar같은 방법을 사용하면 된다. 
소스는 아래와 같다.


#define heartbit_adc_threshold      511
#define meanfilter_size             5
#define heartbit_tick_buffer_size   10
#define measure_buffer_size       3

float meanfilter[meanfilter_size] = {0,};
float measure_buffer[measure_buffer_size] = {0,};
unsigned long heartbit_tick[heartbit_tick_buffer_size] = {0,};
float heartrate_bpm = 0;
float prev_heartrate_bpm = 0;
unsigned long last_heartrate_bpm_update_tick = 0;

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
  for (int i = 0; i < meanfilter_size; i++)
  {
    meanfilter[i] = 0;
  }

  clear_measure_buffer();

  heartrate_bpm = 0;
  prev_heartrate_bpm = 0;
}

float filtering(float val)
{
  int i = 0;
  float mean = 0;
  int cnt = 0;
  float max_val = 0;
  float min_val = 1024;

  for (i = 1; i < meanfilter_size; i++)
  {
    meanfilter[i - 1] = meanfilter[i];
  }

  meanfilter[meanfilter_size - 1] = val;

  for (int i = 0; i < meanfilter_size; i++)
  {
    if (meanfilter[i])
    {
      mean += meanfilter[i];
      cnt++;
      if (max_val < meanfilter[i])
      {
        max_val = meanfilter[i];
      }

      if (min_val > meanfilter[i])
      {
        min_val = meanfilter[i];
      }
    }
  }

  if (max_val)
  {
    mean -= max_val;
    cnt--;
  }

  if (min_val != 1024 && min_val != max_val)
  {
    mean -= min_val;
    cnt--;
  }

  if (cnt > 0)
  {
    return mean / cnt;
  }

  return val;
}

float get_trend(float *signals, int n)
{
  float x = 0, y = 0, a = 0, b = 0;
  float sy = 0.0,
        sxy = 0.0,
        sxx = 0.0;
  int i = 0;

  x = (-n / 2.0 + 0.5);

  while (i < n)
  {
    y = signals[i];
    sy += y;
    sxy += x * y;
    sxx += x * x;

    i++;
    x += 1.0;
  }

  b = sxy / sxx;
  a = sy / n;

  return b;
}

void clear_measure_buffer()
{
  for (int i = 0; i < heartbit_tick_buffer_size; i++)
  {
    heartbit_tick[i] = 0;
  }

}

float prev_trend = 0;
boolean found_high = false;

float measure_heartbitrate(float val, float threshold)
{
  int i = 0;
  float cur_trend = 0;

  found_high = false;

  for (i = 1; i < measure_buffer_size; i++)
  {
    measure_buffer[i - 1] = measure_buffer[i];
  }

  measure_buffer[measure_buffer_size - 1] = val;

  cur_trend = get_trend(measure_buffer, measure_buffer_size);


  if (prev_trend > 0 && cur_trend <= 0 && val > threshold )
  {
    found_high = true;
  }
  prev_trend = cur_trend;


  if (found_high)
  {
    for (i = 1; i < heartbit_tick_buffer_size; i++)
    {
      heartbit_tick[i - 1] = heartbit_tick[i];
    }

    heartbit_tick[heartbit_tick_buffer_size - 1] = millis();

    if (heartbit_tick[0] != 0 && heartbit_tick[heartbit_tick_buffer_size - 1] != 0)
    {
      float timedur = (float)heartbit_tick[heartbit_tick_buffer_size - 1] - (float)heartbit_tick[0];
      float bpm = (((heartbit_tick_buffer_size-1) * 1000) / timedur) * 60;

      if(bpm < 50 || bpm > 120)
      {
        // wrong bpm...
        clear_measure_buffer();
        return 0;
      }

      return bpm;
    }
  }

  return 0;
}

void loop() {
  // put your main code here, to run repeatedly:

  float cur_measure_val = 0;
  unsigned long cur_time_ms = millis();

  float heartbeat_level = filtering(analogRead(A0));

  cur_measure_val = measure_heartbitrate(heartbeat_level, heartbit_adc_threshold);
  if (cur_measure_val)
  {
    heartrate_bpm = cur_measure_val;
    last_heartrate_bpm_update_tick = cur_time_ms;
  }
  else
  {
    if (cur_time_ms - last_heartrate_bpm_update_tick >= 10 * 1000)
    {
      heartrate_bpm = 0;
      last_heartrate_bpm_update_tick = cur_time_ms;
      clear_measure_buffer();
    }
  }

  /*
  */
#if 0
  Serial.print(heartbeat_level);
  Serial.print(" ");
  //Serial.print(heartrate_bpm);
  //Serial.print(" ");

  if (found_high)
  {
    Serial.print(heartbeat_level);
  }
  else
  {
    Serial.print(heartbit_adc_threshold);

  }

  Serial.print("\n");
  #else
    if (prev_heartrate_bpm != heartrate_bpm)
  {
    if (heartrate_bpm)
    {
      Serial.print("HeartBeat Rate :");
      Serial.print(heartrate_bpm);
      Serial.println(" bpm");
    }
    else
    {
      Serial.println("HeartBeat Rate : ..... ");
    }
    
    prev_heartrate_bpm = heartrate_bpm;
  }
#endif

  /**/
  cur_time_ms = millis() - cur_time_ms;
  if (cur_time_ms < 10)
  {
    delay(10 - cur_time_ms);
  }
}


아래 그림은 실제 심박수를 측정한 결과다.


댓글

댓글 쓰기

이 블로그의 인기 게시물

간단한 cfar 알고리즘에 대해

이미지
Constant False Alarm Rate (CFAR)은 기본적으로 테스트하고자 하는 위치의 cell과 주변 cell의 관계를 보고 테스트 cell이 Target 인지 아닌지를 구분하는 알고리즘이다. 주변 cell과의 관계를 어떤 방식으로 비교하는가에 따라 여러가지 알고리즘이 존재한다. CA-CFAR, GO-CFAR, SO-CFAR, OS-CFAR, VI-CFAR, OSVI-CFAR등이 있다. 이 많은 알고리즘 중 간단하고 기본적인 CA-CFAR과 OS-CFAR에 대해 알아보자. CA-CFAR (Cell Average CFAR)   CA-CFAR의 원리는 위 그림과 같다. 좌우의 Reference Cell의 평균에 Scale Factor T를 곱하고, ADT (Average Decision Threshold)를 합하여 CUT가 타겟인지 아닌지를 구분한다. ADT는 신호의 white noise를 고려하기 위해 더해준다. Scale Factor T와 ADT는 아래와 같은 공식으로 사용할 수 있다. 사용하려는 시스템에 따라 공식은 달라질 수도 있다.   Pfa는 False Alarm 발생 확률을 나타내고, M과N는각 좌우의 Reference Cell의 개수를 나타낸다. OS-CFAR (Order Static CFAR)   OS-CFAR의 원리는 위 그림과 같다. 좌우의 reference cell중 K번째 큰 값의 cell을 Reference Cell의 대표 값으로 정해 CUT가 타겟인지 아닌지를 구분한다. 보통 전제 reference cell의 크기 순에서 (3*N)/4 번째 cell이 성능이 좋다고 알려져 있다. CFAR 사용 예 아래 사진은 위 두 cfar을 사용한 예다. 파란색은 신호이며, 붉은 색은 char을 사용해 만든 threshold이다. 이 threshold보다 큰 값의 신호가 있는 위치에 실제 Target이 있다고 볼 수 있
자세한 내용 보기

쉽게 설명한 파티클 필터(particle filter) 동작 원리와 예제

이미지
파티클 필터(particle filter)는 칼만 필터(kalman filter) 와 마찬가지로 노이즈가 있는 환경에서 측정된 데이터를 필터를 사용해 실제 위치를 추정하는 도구다. 파티클 필터(particle filter)는 보통 가우시안 분포가 아닌 측정 데이터를 다루기 위해 사용된다고 한다. 물론 가우시안 분포의 데이터에서 사용하지 말라는 건 아니다.  본 포스트에서는 파티클 필터(particle filter)의 어려운 수학적인 내용은 제하고, 쉽게 예를 들며 필터의 동작원리에 대해 알아보았다. 파티클 필터(particle filter)에 대해 검색해 보면 아래와 같은 그림을 많이 보게 된다. 아래 그림은 파티클 필터의 estimation cycle을 도식화한 것이다. <’Real-Time Tracking of Multiple Moving Objects Using Particle Filters and Probabilistic Data Association’ original scientific paper 中> 위 그림의 검은색 원들은 particle을 의미한다. 이 particle에는 보통 위치 데이터와 weight가 포함된다. 검은색 원이 큰 것이 있고 작은 것이 있는 이유는 weight가 크고 작음을 의마한다. typedef struct _particle_t {    int x;    int y;    float weight; }particle_t; 노이즈가 있는 환경에서 레이저 센서나 레이더등을 이용하여 물체의 위치를 측정할 때를 가정해 순서대로 이 필터가 동작하는 과정에 대해 알아 보겠다. (순서는 위 그림과 조금 다르다) 1. 초기 상태 측정 범위안에 랜덤 혹은 일정한 간경으로 particle을 뿌려 놓는다. 이 떄 particle의 weight는 모두 0으로 한다.   for(i
자세한 내용 보기

windows에서 간단하게 크롬캐스트(Chromecast)를 통해 윈도우 화면 미러링 방법

이미지
 Windows 10에서는 미라캐스트를 사용한 무선 디스플레이연결을 지원한다. 하지만, 만약 크롬캐스트(Chromecast)를 사용해 윈도우 화면을 미러링 하고자 할 때, 구글 크롬 브라우저를 사용하면 쉽고 편하게 할 수 있다. https://www.google.co.kr/intl/ko/chrome/ VLC에서도 비디오 화면을 미러링 할 수 있다고 하는데, 잘 동작하지 않고 윈도우 화면 전체를 미러링하지 않아 크롬 브라우저를 사용하고 있다. 크롬 캐스트 윈도우 화면 전송 방법 0. 크롬 캐스트 디바이스와 windows pc는 같은 네트웍에 연결되어 있어야 한다. (같은 공유기에 연결되어 있어야 한다.) 1. 크롬 브라우저의 우측 상단의 메뉴 > 전송을 클릭하면, 현재 사용가능한 크롬캐스트 디바이스 항목을 볼 수 있다. 2. 편의에 따라 탭 전송 아이콘에서 우측 버튼을 클릭하여 항상 표시되게 설정할 수도 있다. 3.  윈도우 화면 전체를 전송하고자 할 때는 탭 전송의 소스에서 '데스크톱 전송'을 선택하고, 바로 위의 크롬캐스트 디바이스를 클릭하면 된다. ** 소스는 미러링 중에는 변경되지 않는다. 먼저 소스를 선택하고 미러링해야 한다.  4. 화면 전송을 끝내고자 할 때는, 탭 전송에서 화면 전송중인 크롬캐스트 디바이스를 클릭하거나, 크롬 브라우저를 종료하면 된다.
자세한 내용 보기

mkfs.fat Device or resource busy 에러 해결법

이미지
 리눅스에서 SD 카드를 포맷할 때 아래와 같이 "Device or resource busy"에러를 출력하며 포맷이 되지 않는 경우가 있다. mkfs.fat: unable to open /dev/mmcblk0p1: Device or resource busy 해결법을 찾아보았다. 이 문제의 원인은  1. 파티션 dev path 가 맞지 않거나,  2. umount가 완전히 이루어 지지 않았거나,  3. mbr파티션에 문제가 있어 발생한다고 한다.  파티션에 문제가 있는 경우 fdisk를 사용하면 문제를 해결할 수 있다. umount에 문제가 있는 경우, umount할 때 -l 옵션이 사용되는 경우 umount 명령이 끝나도 커널 내부에서 리소스가 계속 사용될 가능성이 있다고 한다.  # umount -l /mnt/mmc umount2("/mnt/mmc",MNT_DETACH); 이런 경우 일정 시간 후 다시 시도하면 에러 없이 포맷이 되는 경우가 있다. 또, umount 가 되지 않을 때 "lsof" , "fuser" 명령어를 사용하여 어떤 프로세스가 mmc를 사용하고 있는지도 확인 가능하다. * lsof에서 사용 내역이 없다고 나와도, fuser에서 나올수 있다.  lsof, fuser 명령에서도 mmc를 사용하는 프로세스가 없는 경우에도 "Device or resource busy"에러가 발생할 경우, umount에 -lf 옵션을 두어 강제로 언마운트 후 SD 카드를 포맷하면 "Device or resource busy"에러가 나타나지 않을 확률이 높아진다. # umount -lf /mnt/mmc umount2("/mnt/mmc",MNT_DETACH | MNT_FORCE); * fat32에서는 "-f","
자세한 내용 보기